Tutorial Membuat aplikasi Client server 2 arah (lanjutan) dengan VB 6
Diposting oleh : Administrator
Kategori: VB - Dibaca: 726 kali

Sekarang kami akan membahas Tutorial Membuat aplikasi Client server 2 arah (lanjutan) dengan VB 6 setalah membahas Client server 2 arah dengan VB 6 pada artikel sebelumnya.

Server Side

1. Buatlah sebuah form dalam Visual Basic (VB) untuk sisi server, selanjutnya masukkan beberapa komponen sehingga tampilan menjadi seperti gambar dibawah, adapun komponen yang dibutuhkan dapat dilihat pada tabel dibawah gambar.


Komponen Property




2. Buat variable global dalam jendela view code, pilih pada tab (general) - (Declaration)
Ketiklah source code dibawah ini
Option Explicit
Dim svrPort As String
Dim msg As String

3. Selanjutnya ketikkan code dibawah ini kedalam komponen objek yang mengalami event/action pada tabel diatas, diantaranya objek Form, commandbutton dan Winsock.

Private Sub cmdListen_Click()
svrPort = txtServerPort.Text
wskServer.Close
wskServer.LocalPort = svrPort
wskServer.Listen
lblStatus.Caption = "Waiting for connection..."
txtServerPort.Enabled = False
cmdListen.Enabled = False
cmdStop.Enabled = True
End Sub

Private Sub cmdSend_Click()
msg = txtMsg.Text
If wskServer.State = sckConnected Then
ListChat.AddItem " " & msg
wskServer.SendData msg
DoEvents
txtMsg.Text = ""
Else
ListChat.AddItem "* No connection found..."
End If
End Sub

Private Sub cmdStop_Click()
wskServer.Close
lblStatus.Caption = "Server is closed..."
txtServerPort.Enabled = True
cmdStop.Enabled = False
cmdListen.Enabled = True
ListChat.AddItem "* Session Closed..."
End Sub

Private Sub Form_Load()
txtServerIP.Text = wskServer.LocalIP
txtServerIP.Enabled = False
txtServerPort.Text = "12345"
cmdStop.Enabled = False
End Sub



Private Sub wskServer_Close()
If wskServer.State <> sckClosed Then wskServer.Close
cmdListen_Click
txtChat.Text = "* The Client have Quit the Session..."
End Sub

Private Sub wskServer_ConnectionRequest(ByVal requestID As Long)
wskServer.Close
wskServer.Accept requestID
lblStatus.Caption = "Connection Success..."
ListChat.AddItem "* The Client is Successfully Connected..."
End Sub

Private Sub wskServer_DataArrival(ByVal bytesTotal As Long)
wskServer.GetData msg
DoEvents
ListChat.AddItem " " & msg
End Sub

Private Sub wskServer_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
MsgBox " Terjadi error pada koneksi anda, periksa ip / port ", vbCritical + vbOKOnly, "Error"
End Sub

1. Simpan project yang anda buat pada folder tersendiri, beri nama prjServer untuk nama projectnya dan FrmServer untuk formnya.

Side

1. Buatlah sebuah form dalam Visual Basic (VB) untuk sisi client, selanjutnya masukkan beberapa komponen sehingga tampilan menjadi seperti gambar dibawah, adapun komponen yang dibutuhkan dapat dilihat pada tabel dibawah gambar.


Komponen Property


2. Buat variabel global dalam jendela view code, pilih pada tab (general) - (Declarations)Ketiklah source dibawah ini

Option Explicit
Dim svrPort As String
Dim svrIP As String
Dim msg As String

3. Selanjutnya ketikkan code dibawah ini kedalam komponen objek yang mengalami event/action pada tabel diatas, diantaranya objek Form, commandbutton dan Winsock.

Private Sub cmdConnect_Click()
svrPort = txtServerPort.Text
svrIP = txtServerIP.Text
wskClient.Close
wskClient.RemoteHost = svrIP
wskClient.RemotePort = svrPort
wskClient.Connect
txtServerPort.Enabled = False
txtServerIP.Enabled = False
cmdConnect.Enabled = False
cmdDisconnect.Enabled = True
lblStatus.Caption = "Connecting to server..."
End Sub

Private Sub cmdDisconnect_Click()
wskClient.Close
lblStatus.Caption = "Disconnected to server..."
txtServerPort.Enabled = True
txtServerIP.Enabled = True
cmdConnect.Enabled = True
cmdDisconnect.Enabled = False
ListChat.AddItem "* Disconnected..."
End Sub




Private Sub cmdSend_Click()
msg = txtMsg.Text
If wskClient.State = sckConnected Then
ListChat.AddItem " " & msg
wskClient.SendData msg
DoEvents
txtMsg.Text = ""
Else
ListChat.AddItem "* Not connected to server..."
End If
End Sub

Private Sub Form_Load()
txtServerPort.Text = "12345"
txtServerIP.Text = wskClient.LocalIP
cmdDisconnect.Enabled = False
End Sub

Private Sub wskClient_Close()
If wskClient.State <> sckClosed Then wskClient.Close
MsgBox "Connection to server lost...", vbInformation + vbOKOnly, "Error"
cmdDisconnect_Click
End Sub

Private Sub wskClient_Connect()
If wskClient.State <> sckClosed Then
lblStatus.Caption = "Connected to server..."
End If
ListChat.AddItem "* Welcome To Chat, Feel Free To Talk Anything..."
End Sub

Private Sub wskClient_DataArrival(ByVal bytesTotal As Long)
wskClient.GetData msg
ListChat.AddItem " " & msg
DoEvents
End Sub

Private Sub wskClient_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
MsgBox "Could not connect to server...", vbInformation + vbOKOnly, "Error 1"
cmdDisconnect_Click
End Sub

1. Simpan project yang anda buat pada folder tersendiri, beri nama prjClient untuk nama projectnya dan FrmClient untuk formnya.